{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE DeriveGeneric #-}
{-# LANGUAGE DuplicateRecordFields #-}

module ZGoTx where

import Data.Aeson
import qualified Data.Bson as B
import Data.Char
import Data.Maybe
import qualified Data.Text as T
import qualified Data.UUID as U
import Data.Void
import Database.MongoDB
import GHC.Generics
import Text.Megaparsec hiding (State)
import Text.Megaparsec.Char

-- | Type to model a ZGo transaction
data ZGoTx =
  ZGoTx
    { _id :: Maybe ObjectId
    , address :: T.Text
    , session :: T.Text
    , confirmations :: Integer
    , blocktime :: Integer
    , amount :: Double
    , txid :: T.Text
    , memo :: T.Text
    }
  deriving (Eq, Show, Generic)

parseZGoTxBson :: B.Document -> Maybe ZGoTx
parseZGoTxBson d = do
  i <- B.lookup "_id" d
  a <- B.lookup "address" d
  s <- B.lookup "session" d
  c <- B.lookup "confirmations" d
  am <- B.lookup "amount" d
  t <- B.lookup "txid" d
  m <- B.lookup "memo" d
  bt <- B.lookup "blocktime" d
  pure $ ZGoTx i a s c bt am t m

encodeZGoTxBson :: ZGoTx -> B.Document
encodeZGoTxBson (ZGoTx i a s c bt am t m) =
  if not (null i)
    then [ "_id" =: i
         , "address" =: a
         , "session" =: s
         , "confirmations" =: c
         , "blocktime" =: bt
         , "amount" =: am
         , "txid" =: t
         , "memo" =: m
         ]
    else [ "address" =: a
         , "session" =: s
         , "confirmations" =: c
         , "blocktime" =: bt
         , "amount" =: am
         , "txid" =: t
         , "memo" =: m
         ]

instance Val ZGoTx where
  cast' (Doc d) = do
    i <- B.lookup "_id" d
    a <- B.lookup "address" d
    s <- B.lookup "session" d
    c <- B.lookup "confirmations" d
    am <- B.lookup "amount" d
    t <- B.lookup "txid" d
    m <- B.lookup "memo" d
    bt <- B.lookup "blocktime" d
    Just (ZGoTx i a s c bt am t m)
  cast' _ = Nothing
  val (ZGoTx i a s c bt am t m) =
    case i of
      Just oid ->
        Doc
          [ "_id" =: i
          , "address" =: a
          , "session" =: s
          , "confirmations" =: c
          , "blocktime" =: bt
          , "amount" =: am
          , "txid" =: t
          , "memo" =: m
          ]
      Nothing ->
        Doc
          [ "address" =: a
          , "session" =: s
          , "confirmations" =: c
          , "blocktime" =: bt
          , "amount" =: am
          , "txid" =: t
          , "memo" =: m
          ]

-- | Type to represent and parse ZGo memos
data ZGoMemo =
  ZGoMemo
    { m_session :: Maybe U.UUID
    , m_address :: Maybe T.Text
    , m_payment :: Bool
    }
  deriving (Eq, Show)

data MemoToken
  = Login !U.UUID
  | PayMsg !U.UUID
  | Address !T.Text
  | Msg !T.Text
  deriving (Show, Eq)

type Parser = Parsec Void T.Text

pSession :: Parser MemoToken
pSession = do
  string "ZGO"
  pay <- optional $ char 'p'
  string "::"
  s <- some $ hexDigitChar <|> char '-'
  let u = U.fromString s
  case u of
    Nothing -> fail "Invalid UUID"
    Just u' -> do
      if isJust pay
        then pure $ PayMsg u'
        else pure $ Login u'

pSaplingAddress :: Parser MemoToken
pSaplingAddress = do
  string "zs"
  a <- some alphaNumChar
  if length a /= 76
    then fail "Failed to parse Sapling address"
    else pure $ Address $ T.pack ("zs" <> a)

pMsg :: Parser MemoToken
pMsg = do
  Msg . T.pack <$>
    some
      (alphaNumChar <|> punctuationChar <|> symbolChar <|>
       charCategory OtherSymbol)

pMemo :: Parser MemoToken
pMemo = do
  optional spaceChar
  pSession <|> pSaplingAddress <|> pMsg

isMemoToken :: T.Text -> MemoToken -> Bool
isMemoToken kind t =
  case kind of
    "session" ->
      case t of
        PayMsg i -> True
        Login j -> True
        _ -> False
    "address" ->
      case t of
        Address a -> True
        _ -> False
    "payment" ->
      case t of
        PayMsg i -> True
        _ -> False
    _ -> False

pZGoMemo :: Parser ZGoMemo
pZGoMemo = do
  tks <- some pMemo
  pure $ ZGoMemo (isSession tks) (isAddress tks) (isPayment tks)
  where
    isPayment [] = False
    isPayment tks =
      not (null tks) &&
      case head tks of
        PayMsg x -> True
        _ -> isPayment $ tail tks
    isAddress [] = Nothing
    isAddress tks =
      if not (null tks)
        then case head tks of
               Address x -> Just x
               _ -> isAddress $ tail tks
        else Nothing
    isSession [] = Nothing
    isSession tks =
      if not (null tks)
        then case head tks of
               Login x -> Just x
               PayMsg y -> Just y
               _ -> isSession $ tail tks
        else Nothing